ParaViewTesting.cmake
Go to the documentation of this file.
1 function (paraview_add_test_python)
2  set(_vtk_testing_python_exe "$<TARGET_FILE:ParaView::pvpython>")
3  set(_vtk_test_python_args --dr ${paraview_python_args})
4  vtk_add_test_python(${ARGN})
5 endfunction ()
6 
7 function (paraview_add_test_pvbatch)
8  set(_vtk_testing_python_exe "$<TARGET_FILE:ParaView::pvbatch>")
9  set(_vtk_test_python_args --dr ${paraview_pvbatch_args})
10  set(vtk_test_prefix "Batch-${vtk_test_prefix}")
11  vtk_add_test_python(${ARGN})
12 endfunction ()
13 
14 function (paraview_add_test_pvbatch_mpi)
15  set(_vtk_testing_python_exe "$<TARGET_FILE:ParaView::pvbatch>")
16  set(_vtk_test_python_args --dr ${paraview_pvbatch_args})
17  set(vtk_test_prefix "Batch-${vtk_test_prefix}")
18  vtk_add_test_python_mpi(${ARGN})
19 endfunction ()
20 
21 function(paraview_add_test_driven)
22  if (NOT (TARGET pvserver AND TARGET pvpython))
23  return()
24  endif ()
25  set(_vtk_testing_python_exe "$<TARGET_FILE:ParaView::smTestDriver>")
26  set(_vtk_test_python_args
27  --server $<TARGET_FILE:ParaView::pvserver>
28  --client $<TARGET_FILE:ParaView::pvpython> --dr)
29  vtk_add_test_python(${ARGN})
30 endfunction ()
31 
32 function (_paraview_add_tests function)
33  cmake_parse_arguments(_paraview_add_tests
34  "FORCE_SERIAL;FORCE_LOCK;SMTESTING_ALLOW_ERRORS"
35  "LOAD_PLUGIN;PLUGIN_PATH;CLIENT;TEST_DIRECTORY;TEST_DATA_TARGET;PREFIX;SUFFIX;_ENABLE_SUFFIX;_DISABLE_SUFFIX;BASELINE_DIR;DATA_DIRECTORY;NUMPROCS;NUMSERVERS"
36  "_COMMAND_PATTERN;LOAD_PLUGINS;PLUGIN_PATHS;TEST_SCRIPTS;TEST_NAME;ENVIRONMENT;ARGS;CLIENT_ARGS"
37  ${ARGN})
38  # NUMSERVERS is not used here, but is used by paraview_add_client_server_tests function.
39  # It is kept here to avoid filtering it out from ARGN in the caller.
40  # If it were not present here, nor filtered out in the caller, then it would be considered
41  # as part of "TEST_SCRIPTS" multivalue argument.
42 
43  if (_paraview_add_tests_UNPARSED_ARGUMENTS)
44  message(FATAL_ERROR
45  "Unparsed arguments for ${function}: "
46  "${_paraview_add_tests_UNPARSED_ARGUMENTS}")
47  endif ()
48 
49  if (NOT DEFINED _paraview_add_tests__COMMAND_PATTERN)
50  message(FATAL_ERROR
51  "The `_COMMAND_PATTERN` argument is required.")
52  endif ()
53 
54  if (NOT DEFINED _paraview_add_tests_CLIENT)
55  if ("__paraview_client__" IN_LIST _paraview_add_tests__COMMAND_PATTERN # do we care?
56  AND NOT TARGET ParaView::paraview # For external testing.
57  AND NOT paraview_will_be_built) # For use within ParaView itself.
58  return ()
59  endif ()
60 
61  set(_paraview_add_tests_CLIENT
62  "$<TARGET_FILE:ParaView::paraview>")
63  endif ()
64 
65  if (NOT DEFINED _paraview_add_tests_PREFIX)
66  set(_paraview_add_tests_PREFIX "pv")
67  endif ()
68 
69  if (NOT DEFINED _paraview_add_tests_TEST_DIRECTORY)
70  if (NOT DEFINED PARAVIEW_TEST_DIR)
71  set(_paraview_add_tests_TEST_DIRECTORY
72  "${CMAKE_BINARY_DIR}/Testing/Temporary")
73  else()
74  set(_paraview_add_tests_TEST_DIRECTORY
75  "${PARAVIEW_TEST_DIR}")
76  set(_vtk_build_TEST_OUTPUT_DIRECTORY "${PARAVIEW_TEST_DIR}")
77  endif()
78  endif ()
79 
80  if (NOT DEFINED _paraview_add_tests_DATA_DIRECTORY AND DEFINED _paraview_add_tests_default_data_directory)
81  set(_paraview_add_tests_DATA_DIRECTORY
82  "${_paraview_add_tests_default_data_directory}")
83  endif ()
84 
85  if (DEFINED _paraview_add_tests_TEST_SCRIPTS AND DEFINED _paraview_add_tests_TEST_NAME)
86  message(FATAL_ERROR
87  "Only one of `TEST_NAME` or `TEST_SCRIPTS` must be specified.")
88  elseif (NOT DEFINED _paraview_add_tests_TEST_SCRIPTS AND NOT DEFINED _paraview_add_tests_TEST_NAME)
89  message(FATAL_ERROR
90  "Either `TEST_SCRIPTS` or `TEST_NAME` must be specified.")
91  endif()
92 
93  set(_paraview_add_tests_args
94  ${_paraview_add_tests_ARGS})
95 
96  if (DEFINED _paraview_add_tests_PLUGIN_PATH)
97  list(APPEND _paraview_add_tests_args
98  "--plugin-search-paths=${_paraview_add_tests_PLUGIN_PATH}")
99  endif ()
100 
101  if (DEFINED _paraview_add_tests_PLUGIN_PATHS)
102  string(REPLACE ";" "," _plugin_paths "${_paraview_add_tests_PLUGIN_PATHS}")
103  list(APPEND _paraview_add_tests_args
104  "--plugin-search-paths=${_plugin_paths}")
105  endif ()
106 
107  if (DEFINED _paraview_add_tests_LOAD_PLUGIN)
108  list(APPEND _paraview_add_tests_args
109  "--plugins=${_paraview_add_tests_LOAD_PLUGIN}")
110  endif ()
111 
112  if (DEFINED _paraview_add_tests_LOAD_PLUGINS)
113  string(REPLACE ";" "," _load_plugins "${_paraview_add_tests_LOAD_PLUGINS}")
114  list(APPEND _paraview_add_tests_args
115  "--plugins=${_load_plugins}")
116  endif ()
117 
118  string(REPLACE "__paraview_args__" "${_paraview_add_tests_args}"
119  _paraview_add_tests__COMMAND_PATTERN
120  "${_paraview_add_tests__COMMAND_PATTERN}")
121  string(REPLACE "__paraview_client__" "${_paraview_add_tests_CLIENT}"
122  _paraview_add_tests__COMMAND_PATTERN
123  "${_paraview_add_tests__COMMAND_PATTERN}")
124 
125  foreach (_paraview_add_tests_script IN LISTS _paraview_add_tests_TEST_SCRIPTS _paraview_add_tests_TEST_NAME)
126  if (DEFINED _paraview_add_tests_TEST_NAME)
127  set(_paraview_add_tests_name "${_paraview_add_tests_script}")
128  set(_paraview_add_tests_name_base "${_paraview_add_tests_name}")
129  set(_paraview_add_tests_script)
130  else()
131  if (NOT IS_ABSOLUTE "${_paraview_add_tests_script}")
132  set(_paraview_add_tests_script
133  "${CMAKE_CURRENT_SOURCE_DIR}/${_paraview_add_tests_script}")
134  endif ()
135  get_filename_component(_paraview_add_tests_name "${_paraview_add_tests_script}" NAME_WE)
136  set(_paraview_add_tests_name_base "${_paraview_add_tests_name}")
137  endif()
138 
139  string(APPEND _paraview_add_tests_name "${_paraview_add_tests_SUFFIX}")
140 
141  if (DEFINED _paraview_add_tests__DISABLE_SUFFIX AND ${_paraview_add_tests_name}${_paraview_add_tests__DISABLE_SUFFIX})
142  continue ()
143  endif ()
144 
145  if (DEFINED _paraview_add_tests__ENABLE_SUFFIX AND NOT ${_paraview_add_tests_name}${_paraview_add_tests__ENABLE_SUFFIX})
146  continue ()
147  endif ()
148 
149  if (NOT DEFINED _paraview_add_tests_TEST_DATA_TARGET)
150  if (DEFINED _paraview_add_tests_default_test_data_target)
151  set(_paraview_add_tests_TEST_DATA_TARGET
152  "${_paraview_add_tests_default_test_data_target}")
153  else()
154  if (NOT DEFINED "${_paraview_add_tests_name}_USES_DIRECT_DATA")
155  message(FATAL_ERROR "The `TEST_DATA_TARGET` argument is required.")
156  endif()
157  endif ()
158  endif ()
159 
160  # Build arguments to pass to smTestDriver
161  set(_paraview_add_tests_smtesting_args "")
162  if (_paraview_add_tests_SMTESTING_ALLOW_ERRORS)
163  list(APPEND _paraview_add_tests_smtesting_args "--allow-errors")
164  endif ()
165 
166  # Build arguments to pass to the clients.
167  set(_paraview_add_tests_client_args
168  "--test-directory=${_paraview_add_tests_TEST_DIRECTORY}"
169  ${_paraview_add_tests_CLIENT_ARGS})
170  if (DEFINED _paraview_add_tests_BASELINE_DIR)
171  if (DEFINED "${_paraview_add_tests_name}_BASELINE")
172  if (DEFINED "${_paraview_add_tests_name}_USES_DIRECT_DATA")
173  list(APPEND _paraview_add_tests_client_args
174  "--test-baseline=${_paraview_add_tests_BASELINE_DIR}/${${_paraview_add_tests_name_base}_BASELINE}")
175  else()
176  list(APPEND _paraview_add_tests_client_args
177  "--test-baseline=DATA{${_paraview_add_tests_BASELINE_DIR}/${${_paraview_add_tests_name_base}_BASELINE}}")
178  endif ()
179  else ()
180  if (DEFINED "${_paraview_add_tests_name}_USES_DIRECT_DATA")
181  list(APPEND _paraview_add_tests_client_args
182  "--test-baseline=${_paraview_add_tests_BASELINE_DIR}/${_paraview_add_tests_name_base}.png")
183  else()
184  list(APPEND _paraview_add_tests_client_args
185  "--test-baseline=DATA{${_paraview_add_tests_BASELINE_DIR}/${_paraview_add_tests_name_base}.png}")
186  endif ()
187  endif ()
188  if (NOT DEFINED "${_paraview_add_tests_name}_USES_DIRECT_DATA")
189  ExternalData_Expand_Arguments("${_paraview_add_tests_TEST_DATA_TARGET}" _
190  "DATA{${_paraview_add_tests_BASELINE_DIR}/,REGEX:${_paraview_add_tests_name_base}(-.*)?(_[0-9]+)?.png}")
191  endif()
192  endif ()
193  if (DEFINED "${_paraview_add_tests_name}_THRESHOLD")
194  list(APPEND _paraview_add_tests_client_args
195  "--test-threshold=${${_paraview_add_tests_name}_THRESHOLD}")
196  endif ()
197  if (DEFINED _paraview_add_tests_DATA_DIRECTORY)
198  list(APPEND _paraview_add_tests_client_args
199  "--data-directory=${_paraview_add_tests_DATA_DIRECTORY}")
200  endif ()
201 
202  if (DEFINED _paraview_add_tests_TEST_NAME)
203  string(REPLACE "__paraview_script__" ""
204  _paraview_add_tests_script_args
205  "${_paraview_add_tests__COMMAND_PATTERN}")
206  string(REPLACE "__paraview_scriptpath__" ""
207  _paraview_add_tests_script_args
208  "${_paraview_add_tests_script_args}")
209  else()
210  string(REPLACE "__paraview_script__" "--test-script=${_paraview_add_tests_script}"
211  _paraview_add_tests_script_args
212  "${_paraview_add_tests__COMMAND_PATTERN}")
213  string(REPLACE "__paraview_scriptpath__" "${_paraview_add_tests_script}"
214  _paraview_add_tests_script_args
215  "${_paraview_add_tests_script_args}")
216  endif()
217 
218  string(REPLACE "__paraview_client_args__" "${_paraview_add_tests_client_args}"
219  _paraview_add_tests_script_args
220  "${_paraview_add_tests_script_args}")
221  string(REPLACE "__paraview_test_name__" "${_paraview_add_tests_name_base}"
222  _paraview_add_tests_script_args
223  "${_paraview_add_tests_script_args}")
224  string(REPLACE "__paraview_smtesting_args__" "${_paraview_add_tests_smtesting_args}"
225  _paraview_add_tests_script_args
226  "${_paraview_add_tests_script_args}")
227 
228  set(testArgs
229  NAME "${_paraview_add_tests_PREFIX}.${_paraview_add_tests_name}"
230  COMMAND ParaView::smTestDriver
231  --enable-bt
232  ${_paraview_add_tests_script_args})
233  if (DEFINED "${_paraview_add_tests_name}_USES_DIRECT_DATA")
234  add_test(${testArgs})
235  else()
236  ExternalData_add_test("${_paraview_add_tests_TEST_DATA_TARGET}" ${testArgs})
237  endif()
238 
239  set_property(TEST "${_paraview_add_tests_PREFIX}.${_paraview_add_tests_name}"
240  PROPERTY
241  LABELS ParaView)
242  set_property(TEST "${_paraview_add_tests_PREFIX}.${_paraview_add_tests_name}"
243  PROPERTY
244  ENVIRONMENT "${_paraview_add_tests_ENVIRONMENT}")
245  if (DEFINED "${_paraview_add_tests_name}_TIMEOUT")
246  set_property(TEST "${_paraview_add_tests_PREFIX}.${_paraview_add_tests_name}"
247  PROPERTY
248  TIMEOUT ${${_paraview_add_tests_name}_TIMEOUT}
249  )
250  endif()
251  if (DEFINED _paraview_add_tests_NUMPROCS)
252  set_property(TEST "${_paraview_add_tests_PREFIX}.${_paraview_add_tests_name}"
253  PROPERTY
254  PROCESSORS "${_paraview_add_tests_NUMPROCS}")
255  endif ()
256  if (${_paraview_add_tests_name}_FORCE_SERIAL OR _paraview_add_tests_FORCE_SERIAL)
257  set_property(TEST "${_paraview_add_tests_PREFIX}.${_paraview_add_tests_name}"
258  PROPERTY
259  RUN_SERIAL ON)
260  elseif (NOT DEFINED _paraview_add_tests_TEST_NAME AND EXISTS "${_paraview_add_tests_script}")
261  # if the XML test contains PARAVIEW_TEST_ROOT we assume that we may be writing
262  # to that file and reading it back in so we add a resource lock on the XML
263  # file so that the pv.X, pvcx.X and pvcrs.X tests don't run simultaneously.
264  # we only need to do this if the test isn't forced to be serial already.
265  if (NOT IS_DIRECTORY "${_paraview_add_tests_script}" AND NOT ${_paraview_add_tests_name}_FORCE_LOCK)
266  file(STRINGS "${_paraview_add_tests_script}" _paraview_add_tests_paraview_test_root REGEX PARAVIEW_TEST_ROOT)
267  endif ()
268  if (${_paraview_add_tests_name}_FORCE_LOCK OR _paraview_add_tests_paraview_test_root)
269  set_property(TEST "${_paraview_add_tests_PREFIX}.${_paraview_add_tests_name}"
270  PROPERTY
271  RESOURCE_LOCK "${_paraview_add_tests_script}")
272  endif ()
273  endif ()
274 
275  # XXX(gitlab-ci): Prevent tests from timing out after a long time. As to
276  # why the tests hang in this situation is not yet known. May be related to
277  # https://gitlab.kitware.com/paraview/paraview/-/issues/20697
278  set_property(TEST "${_paraview_add_tests_PREFIX}.${_paraview_add_tests_name}"
279  PROPERTY
280  TIMEOUT_AFTER_MATCH "5" "Couldn't find object")
281  endforeach ()
282 endfunction ()
283 
284 function(_get_prefix varname default)
285  cmake_parse_arguments(_get_prefix
286  ""
287  "PREFIX"
288  ""
289  ${ARGN})
290  if (_get_prefix_PREFIX)
291  set(${varname} "${_get_prefix_PREFIX}" PARENT_SCOPE)
292  else()
293  set(${varname} "${default}" PARENT_SCOPE)
294  endif()
295 endfunction()
296 
297 # If NUMSERVERS is specified in ${ARGN} then returns in varname the number of servers to use for the test,
298 # otherwise returns the "NOT_FOUND" value.
299 function(_get_num_servers varname)
300  cmake_parse_arguments(_get_num_servers
301  ""
302  "NUMSERVERS"
303  ""
304  ${ARGN})
305  if (_get_num_servers_NUMSERVERS)
306  set(${varname} "${_get_num_servers_NUMSERVERS}" PARENT_SCOPE)
307  else()
308  set(${varname} "NOT_FOUND" PARENT_SCOPE)
309  endif()
310 endfunction()
311 
312 function (paraview_add_client_tests)
313  _get_prefix(chosen_prefix "pv" ${ARGN})
314  _paraview_add_tests("paraview_add_client_tests"
315  PREFIX "${chosen_prefix}"
316  _DISABLE_SUFFIX "_DISABLE_C"
317  _COMMAND_PATTERN
318  __paraview_smtesting_args__
319  --client __paraview_client__
320  --enable-bt
321  __paraview_args__
322  __paraview_script__
323  __paraview_client_args__
324  --dr
325  --exit
326  ${ARGN})
327 endfunction ()
328 
329 function (paraview_add_client_server_tests)
330  _get_prefix(chosen_prefix "pvcs" ${ARGN})
331  set(_paraview_add_tests_args
332  PREFIX "${chosen_prefix}"
333  _DISABLE_SUFFIX "_DISABLE_CS"
334  _COMMAND_PATTERN
335  __paraview_smtesting_args__
336  --server "$<TARGET_FILE:ParaView::pvserver>"
337  --enable-bt
338  __paraview_args__
339  --client __paraview_client__
340  --enable-bt
341  __paraview_args__
342  __paraview_script__
343  __paraview_client_args__
344  --dr
345  --exit
346  ${ARGN}
347  )
348 
349  _get_num_servers(num_servers ${ARGN})
350  if (NOT num_servers STREQUAL "NOT_FOUND")
351  set(_paraview_add_tests_args ${_paraview_add_tests_args};
352  # Set the number of pvservers through the SMTESTDRIVER_MPI_NUMPROCS environment variable.
353  ENVIRONMENT
354  SMTESTDRIVER_MPI_NUMPROCS=${num_servers}
355  # Requires CTest to reserve NUMPROCS among the available processors
356  NUMPROCS "${num_servers}"
357  )
358  endif()
359 
360  _paraview_add_tests("paraview_add_client_server_tests" ${_paraview_add_tests_args})
361 endfunction ()
362 
363 function (paraview_add_client_server_render_tests)
364  _get_prefix(chosen_prefix "pvcrs" ${ARGN})
365  _paraview_add_tests("paraview_add_client_server_render_tests"
366  PREFIX "${chosen_prefix}"
367  _DISABLE_SUFFIX "_DISABLE_CRS"
368  _COMMAND_PATTERN
369  __paraview_smtesting_args__
370  --data-server "$<TARGET_FILE:ParaView::pvdataserver>"
371  --enable-bt
372  __paraview_args__
373  --render-server "$<TARGET_FILE:ParaView::pvrenderserver>"
374  --enable-bt
375  __paraview_args__
376  --client __paraview_client__
377  --enable-bt
378  __paraview_args__
379  __paraview_script__
380  __paraview_client_args__
381  --dr
382  --exit
383  ${ARGN})
384 endfunction ()
385 
386 function (paraview_add_multi_server_tests count)
387  _get_prefix(chosen_prefix "pvcs-multi-servers" ${ARGN})
388  _paraview_add_tests("paraview_add_multi_server_tests"
389  PREFIX "${chosen_prefix}"
390  SUFFIX "-${count}"
391  _COMMAND_PATTERN
392  __paraview_smtesting_args__
393  --test-multi-servers "${count}"
394  --server "$<TARGET_FILE:ParaView::pvserver>"
395  --enable-bt
396  --client __paraview_client__
397  --enable-bt
398  __paraview_args__
399  __paraview_script__
400  __paraview_client_args__
401  --dr
402  --exit
403  ${ARGN})
404 endfunction ()
405 
406 function (paraview_add_tile_display_tests width height)
407  math(EXPR _paraview_add_tile_display_cpu_count "${width} * ${height}")
408 
409  if (_paraview_add_tile_display_cpu_count GREATER 1 AND NOT PARAVIEW_USE_MPI)
410  # we can run 1x1 tile display tests on non MPI builds.
411  return ()
412  endif ()
413 
414  _get_prefix(chosen_prefix "pvcs-tile-display" ${ARGN})
415  _paraview_add_tests("paraview_add_tile_display_tests"
416  PREFIX "${chosen_prefix}"
417  SUFFIX "-${width}x${height}"
418  ENVIRONMENT
419  PV_SHARED_WINDOW_SIZE=800x600
420  SMTESTDRIVER_MPI_NUMPROCS=${_paraview_add_tile_display_cpu_count}
421  NUMPROCS "${_paraview_add_tile_display_cpu_count}"
422  _COMMAND_PATTERN
423  __paraview_smtesting_args__
424  --server "$<TARGET_FILE:ParaView::pvserver>"
425  --enable-bt
426  --tdx=${width}
427  --tdy=${height}
428  # using offscreen to avoid clobbering display (although should not be
429  # necessary) when running tests in parallel.
430  --force-offscreen-rendering
431  --client __paraview_client__
432  --enable-bt
433  __paraview_args__
434  __paraview_script__
435  __paraview_client_args__
436  --dr
437  --exit
438  ${ARGN})
439 endfunction ()
440 
441 function (paraview_add_cave_tests num_ranks config)
442  if (num_ranks GREATER 1 AND NOT PARAVIEW_USE_MPI)
443  return ()
444  endif ()
445 
446  get_filename_component(_config_name "${config}" NAME_WE)
447 
448  _get_prefix(chosen_prefix "pvcs-cave-${_config_name}" ${ARGN})
449  _paraview_add_tests("paraview_add_cave_tests"
450  PREFIX "${chosen_prefix}"
451  SUFFIX "-${num_ranks}"
452  ENVIRONMENT
453  PV_SHARED_WINDOW_SIZE=400x300
454  SMTESTDRIVER_MPI_NUMPROCS=${num_ranks}
455  NUMPROCS "${num_ranks}"
456  _COMMAND_PATTERN
457  __paraview_smtesting_args__
458  --server "$<TARGET_FILE:ParaView::pvserver>"
459  --enable-bt
460  # using offscreen to avoid clobbering display (although should not be
461  # necessary) when running tests in parallel.
462  --force-offscreen-rendering
463  --pvx
464  ${config}
465  --client __paraview_client__
466  --enable-bt
467  __paraview_args__
468  __paraview_script__
469  __paraview_client_args__
470  --dr
471  --exit
472  ${ARGN})
473 endfunction ()
474 
475 # This is a catch-all function to run any custom command as the "client"
476 # using th smTestDriver. Note, the command must print "Process started" for
477 # smTestDriver to treat it as started otherwise the test will fail.
478 # The command to execute is passed as {ARGN} and is suffixed by each of the
479 # TEST_SCRIPTS provided, one at at time.
480 function (paraview_add_test)
481  _get_prefix(chosen_prefix "paraview" ${ARGN})
482  _paraview_add_tests("paraview_add_test"
483  PREFIX "${chosen_prefix}"
484  _COMMAND_PATTERN
485  __paraview_smtesting_args__
486  --client
487  __paraview_args__
488  __paraview_scriptpath__
489  ${ARGN})
490 endfunction ()
491 
492 # Same as `paraview_add_test` except makes smTestDriver run the command using
493 # mpi. If `PARAVIEW_USE_MPI` if not defined, this does not add any test.
494 function (paraview_add_test_mpi)
495  if (PARAVIEW_USE_MPI)
496  _get_prefix(chosen_prefix "paraview-mpi" ${ARGN})
497  _paraview_add_tests("paraview_add_test_mpi"
498  PREFIX "${chosen_prefix}"
499  NUMPROCS 2 # See Utilities/TestDriver/CMakeLists.txt (PARAVIEW_MPI_MAX_NUMPROCS)
500  _COMMAND_PATTERN
501  __paraview_smtesting_args__
502  --client-mpi
503  __paraview_args__
504  __paraview_scriptpath__
505  ${ARGN})
506  endif ()
507 endfunction ()
508 
509 
510 # if PARAVIEW_USE_MPI, calls paraview_add_test_mpi(), else calls
511 # paraview_add_test()
512 function (paraview_add_test_mpi_optional)
513  if (PARAVIEW_USE_MPI)
514  paraview_add_test_mpi(${ARGN})
515  else()
516  paraview_add_test(${ARGN})
517  endif()
518 endfunction()
data
data
paraview_add_test_python
function paraview_add_test_python()
Definition: ParaViewTesting.cmake:1
paraview_add_test_driven
function paraview_add_test_driven()
Definition: ParaViewTesting.cmake:21
paraview_add_client_server_tests
function paraview_add_client_server_tests()
Definition: ParaViewTesting.cmake:329
paraview_add_test_pvbatch_mpi
function paraview_add_test_pvbatch_mpi()
Definition: ParaViewTesting.cmake:14
_paraview_add_tests
function _paraview_add_tests(function)
Definition: ParaViewTesting.cmake:32
paraview_add_test_pvbatch
function paraview_add_test_pvbatch()
Definition: ParaViewTesting.cmake:7
Generated by   doxygen 1.8.17 on Wed Mar 27 2024